It is hard to fathom how much $700 Billion dollars actually is. Personally, I'm still working on my first $1 Million. I was thinking, where are the Feds going to get all that money? Do they have any idea? I was thinking that if they used an idea like Alex Tew's "Million Dollar Homepage" to raise money...how big would your screen have to be to view it.
If you are not familiar with the "Million Dollar Homepage", it was a marketing idea for Alex where he sold advertising on a 1,000 x 1,000 pixel image (1 Million pixels) on a web page. The pixels were sold for $1 each. Alex planned to use the money to put himself through college. Once the site obtained international attention, he quickly raised the $1 Million. (wikidedia)
Well, $700B is a LOT more than $1M...but how much bigger. I mean it's just a bunch more zeros, right? How much bigger could it actually be? It's hard to visualize.
Well, if you said as big as 9 football fields, you would be correct. Really! No kidding...9 football fields big to display 700 Billion pixels at 96 DPI. Thats including the 10 yard end zones. Here is the formula
Ok, so it's not quite 700B, but if we throw in some sidelines' advertising we should be able to pick up the full 700B.
Click on the thumbnail for a 1/1000 scale image...meaning 1 pixel on the picture represents 1,000,000 pixels at full scale. The little white dot in the left endzone is the size of Alex Tew's original site.
Here is the code I used to create the image. Note you will need the GDIPlusX library from the VFPX project to run it.
LOCAL ogfx AS xfcGraphics
LOCAL oDrawPath AS xfcGraphicsPath
LOCAL oFillPath AS xfcGraphicsPath
LOCAL oLogoPath AS xfcGraphicsPath
LOCAL oFormat AS xfcStringFormat
CLEAR
WITH _SCREEN.System.Drawing AS xfcDrawing
**ogfx=.Graphics.FromHWnd(_screen.HWnd)
oBMP = .Bitmap.New(1244,552)
ogfx=.Graphics.FromImage(oBMP)
oFillPath = .Drawing2D.GraphicsPath.New()
oDrawPath = .Drawing2D.GraphicsPath.New()
oLogoPath = .Drawing2D.GraphicsPath.New()
oGreen = .Drawing2D.LinearGradientBrush.New( ;
.RectangleF.New(0,0,360,160), ;
.Color.FromRGB(0,180,0), ;
.Color.FromRGB(0,96,0),2)
oWhite = .Pen.New(.Color.White,0.5)
oOrange = .Brushes.Orange
oWhite2 = .Pen.New(.Color.White,1.2)
oFormat = .StringFormat.New()
oFormat.Alignment = .StringAlignment.Center
oLogoPath.AddString("F", ;
.FontFamily.New("Courier New"), ;
1, 30*96/72, ;
.Rectangle.New(140,58,80,80), oFormat)
oFillPath.AddRectangle(0,0,360,160)
** Add border
oDrawPath.AddRectangle(0,0,360,160)
oDrawPath.CloseFigure()
** Add yard lines
FOR i = 30 TO 330 STEP 15
oDrawPath.AddLine(i, 0, i, 160)
oDrawPath.CloseFigure()
ENDFOR
** Add hash marks
FOR i = 30 TO 330 STEP 3
oDrawPath.AddLine(i, 0, i, 3)
oDrawPath.CloseFigure()
oDrawPath.AddLine(i, 57, i, 60)
oDrawPath.CloseFigure()
oDrawPath.AddLine(i, 100, i, 103)
oDrawPath.CloseFigure()
oDrawPath.AddLine(i, 157, i, 160)
oDrawPath.CloseFigure()
ENDFOR
ogfx.UsePrecision = .T.
ogfx.PageUnit = .GraphicsUnit.Pixel
ogfx.PageScale = (12*96)/1000
ogfx.SmoothingMode = .Drawing2D.SmoothingMode.AntiAlias
FOR x = 0 TO 2
xOffset = x*360
FOR y = 0 TO 2
yOffset = y*160
oState = ogfx.Save()
ogfx.TranslateTransform(xOffset,yOffset)
ogfx.FillPath(oGreen, oFillPath)
ogfx.DrawRectangle(oWhite,7,7,0.87,0.87)
ogfx.DrawPath(oWhite, oDrawPath)
ogfx.FillPath(oOrange,oLogoPath)
ogfx.DrawPath(oWhite2,oLogoPath)
ogfx.Restore(oState)
ENDFOR
ENDFOR
oBMP.Save("FootballField.png",_SCREEN.System.Drawing.Imaging.Imageformat.Png)
ENDWITH
My next blog entry will be about how to get financial backing for a manufacturing company to produce 1,080 foot wide computer monitors. It could be a new definition for 1080 HDTV!
NOTE: This was really just an exercise for creating a football field with GDIPlusX. Not really a solution for the economic crisis. I mean...we could try it, but I doubt it would actually raise $700B.